Where can I get a list of all ('major') airports with the following information:

  • Code
  • Name
  • Location (long/lat)

Additional extras:

  • Size (e.g. number of runways, number of passengers per year, number of flights per year)
  • Owner

asked 19 Jan '11, 18:31

rgrp's gravatar image

rgrp ♦♦
501122027
accept rate: 14%


Rob Styles created a data set in the Talis Incubator.

SPARQL endpoint is http://api.talis.com/stores/airports/services/sparql

For example to get an airport location by IATA code (execute):

PREFIX p: <http://dbpedia.org/property/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select * where {
    ?airporturi p:iata 'BRS'; 
        geo:lat ?latitude; 
        geo:long ?longitude;     
        rdfs:label ?label.
}

To see the kind of data available : (execute)

PREFIX p: <http://dbpedia.org/property/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select * where {
    ?airporturi p:iata 'BRS'; 
        ?p ?v.
}

To get basic data on all airports with an IATA code:

PREFIX p: <http://dbpedia.org/property/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select * where {
    ?airporturi p:iata ?code; 
        geo:lat ?latitude; 
        geo:long ?longitude;     
        rdfs:label ?label.
}

Oddly, although the ICAO codes is used in the local URI, it is not available as a property.

link

answered 19 Jan '11, 18:48

kitwallace's gravatar image

kitwallace
67081426
accept rate: 13%

edited 24 Jan '11, 15:49

This is great -- you should add those exemplar queries on the related ckan package: http://ckan.net/package/data-incubator-our-airports

Do you know if you can get the dataset in bulk (alternative is to iterate over the sparql endpoint using limit and offset i suppose ...)

(22 Jan '11, 22:11) rgrp ♦♦

I'll ask about the status of this dataset over on the dataincubator site. I believe that bulk RDF can only be obtained on request but I'll ask.

(22 Jan '11, 23:17) kitwallace
1

Rob Styles confirms that this RDF dataset is not actively maintained. David Megginson at ourairports.com provides the raw data as open data in CSV format for download but apparently does not want to be involved in exporting RDF as well. This source is described in CKAN http://ckan.net/package/ourairports .

(24 Jan '11, 18:50) kitwallace
link

answered 14 Mar '11, 18:25

Josh%20M's gravatar image

Josh M
3112
accept rate: 0%

edited 14 Mar '11, 23:42

rgrp's gravatar image

rgrp ♦♦
501122027

DBpedia can be queried using SPARQL using endpoint http://dbpedia.org/sparql

For example (execute)

    PREFIX dbpprop: <http://dbpedia.org/property/> 
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
    PREFIX dbpedia-owl: <http://dbpedia.org/ontology/> 
    PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    SELECT * WHERE { 
      ?subject rdf:type dbpedia-owl:Airport;
               rdfs:label ?label;
               dbpprop:location ?location;
               geo:lat ?latitude;
               geo:long ?longitude.
      OPTIONAL {?subject dbpprop:icao ?ICAO}.
      OPTIONAL {?subject dbpprop:iata ?IATA}.
      FILTER (lang(?label) = 'en' )
    } LIMIT 50

As of 2011-01-22T16:24 there are 10134 resources of type Airport , 9541 coded with ICAO, 8409 with IATA.

The PREFIX statements are included here but can be omitted if these default prefixes are used (I just discovered )

link

answered 22 Jan '11, 16:25

kitwallace's gravatar image

kitwallace
67081426
accept rate: 13%

edited 23 Jan '11, 09:51

You can get the names and IATA codes of airports using the data.gov.uk transport data (sourced from NaPTAN) from:

http://transport.data.gov.uk/doc/airport

(Note that this is a paginated list.) You can also get the stop areas that are related to each of the airports, which have locations related with them, again from the NaPTAN data, from:

http://transport.data.gov.uk/doc/stop-area?administrativeArea.name=National - National Air

The SPARQL queries at the bottom of each of these pages show illustrate how they're constructed. If you want to query directly, you can use:

PREFIX naptan: <http://transport.data.gov.uk/def/naptan/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
SELECT DISTINCT ?stopPoint_airport ?name ?iataRef ?lat ?long
WHERE {
  ?item a naptan:StopArea ;
    naptan:administrativeArea <http://transport.data.gov.uk/id/administrative-area/145> ;
    skos:prefLabel ?name ;
    geo:lat ?lat ;
    geo:long ?long ;
    naptan:stopPoint [ naptan:airport ?stopPoint_airport ] . 
  ?stopPoint_airport naptan:iataRef ?iataRef . 
} 
LIMIT 20

on the SPARQL endpoint at:

http://services.data.gov.uk/transport/sparql

link

answered 23 Jan '11, 07:40

JeniT's gravatar image

JeniT
463
accept rate: 0%

-1

Wikipedia (and so presumably DBPedia) has these.

link

answered 20 Jan '11, 21:40

Andy%20Mabbett's gravatar image

Andy Mabbett
40113
accept rate: 50%

Got a url?

(20 Jan '11, 22:40) rgrp ♦♦
Your answer
toggle preview

Follow this question

By Email:

Once you sign in you will be able to subscribe for any updates here

By RSS:

Answers

Answers and Comments

Markdown Basics

  • *italic* or _italic_
  • **bold** or __bold__
  • link:[text](http://url.com/ "title")
  • image?![alt text](/path/img.jpg "title")
  • numbered list: 1. Foo 2. Bar
  • to add a line break simply add two spaces to where you would like the new line to be.
  • basic HTML tags are also supported

Tags:

×10
×7
×1

Asked: 19 Jan '11, 18:31

Seen: 3,326 times

Last updated: 19 May, 05:15

powered by OSQA